Rijndael类的实例

下面的代码示例使用 Rijndael 类加密数据，然后将其解密。

Imports System.Security.Cryptography
Imports System.Text
Imports System.IO
Module RijndaelSample
Sub Main()
Try
' Create a new Rijndael object to generate a key
' and initialization vector (IV).
Dim RijndaelAlg As Rijndael = Rijndael.Create
' Create a string to encrypt.
Dim sData As String = "Here is some data to encrypt."
Dim FileName As String = "CText.txt"
' Encrypt text to a file using the file name, key, and IV.
EncryptTextToFile(sData, FileName, RijndaelAlg.Key, RijndaelAlg.IV)
' Decrypt the text from a file using the file name, key, and IV.
Dim Final As String = DecryptTextFromFile(FileName, RijndaelAlg.Key, RijndaelAlg.IV)
' Display the decrypted string to the console.
Console.WriteLine(Final)
Catch e As Exception
Console.WriteLine(e.Message)
End Try
Console.ReadLine()
End Sub
Sub EncryptTextToFile(ByVal Data As String, ByVal FileName As String, ByVal Key() As Byte, ByVal IV() As Byte)
Try
' Create or open the specified file.
Dim fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)
' Create a new Rijndael object.
Dim RijndaelAlg As Rijndael = Rijndael.Create
' Create a CryptoStream using the FileStream
' and the passed key and initialization vector (IV).
Dim cStream As New CryptoStream(fStream, _
RijndaelAlg.CreateEncryptor(Key, IV), _
CryptoStreamMode.Write)
' Create a StreamWriter using the CryptoStream.
Dim sWriter As New StreamWriter(cStream)
Try
' Write the data to the stream
' to encrypt it.
sWriter.WriteLine(Data)
Catch e As Exception
Console.WriteLine("An error occurred: {0}", e.Message)
Finally
' Close the streams and
' close the file.
sWriter.Close()
cStream.Close()
fStream.Close()
End Try
Catch e As CryptographicException
Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
Catch e As UnauthorizedAccessException
Console.WriteLine("A file error occurred: {0}", e.Message)
End Try
End Sub
Function DecryptTextFromFile(ByVal FileName As String, ByVal Key() As Byte, ByVal IV() As Byte) As String
Try
' Create or open the specified file.
Dim fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)
' Create a new Rijndael object.
Dim RijndaelAlg As Rijndael = Rijndael.Create
' Create a CryptoStream using the FileStream
' and the passed key and initialization vector (IV).
Dim cStream As New CryptoStream(fStream, _
RijndaelAlg.CreateDecryptor(Key, IV), _
CryptoStreamMode.Read)
' Create a StreamReader using the CryptoStream.
Dim sReader As New StreamReader(cStream)
' Read the data from the stream
' to decrypt it.
Dim val As String = Nothing
Try
val = sReader.ReadLine()
Catch e As Exception
Console.WriteLine("An Cerror occurred: {0}", e.Message)
Finally
' Close the streams and
' close the file.
sReader.Close()
cStream.Close()
fStream.Close()
End Try
' Return the string.
Return val
Catch e As CryptographicException
Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
Return Nothing
Catch e As UnauthorizedAccessException
Console.WriteLine("A file error occurred: {0}", e.Message)
Return Nothing
End Try
End Function
End Module


	\| 网站首页 \| VB.Net实例分析 \| .Net技术文摘 \| 下载中心 \| VB.Net书籍笔记 \| .Net源码 \| VBS脚本与组件调用 \| Windows2008技术文摘 \| 给我们留言 \|